@echo off

echo -----------------------------------------------------------
echo --- Synchronizes the UG-directory with the NX-directory ---
echo -----------------------------------------------------------
echo ---        V 1.0 by Eugen Hoeglinger - 12.11.2018       ---
echo -----------------------------------------------------------
echo.

rem +++  WICHTIG: Die nächste Zeile an die aktuelle NX Version anpassen  +++
set NX_VERSION=NX12

rem --- Das Ursprungsverzeichnis setzen
set EA_SERVER_DIR=\\engel.int\nx\ea\ug\%NX_VERSION%_NXTC
set EA_SOURCE_DIR=%EA_SERVER_DIR%\global
rem --- Das Log-Verzeichnis setzen
set LOG_DIR=\\engel.int\nx\ea\NX\Logfiles

rem --- Das Zielverzeichnis setzen
set NX_SERVER_DIR=\\engel.int\nx\ea\NX\NX_PRODUCTIVE\NX-Environment\%NX_VERSION%
set NX_DEST_DIR=%NX_SERVER_DIR%\NX-Config

rem --- UGII_ENV.DAT Verzeichnisse setzen
set ENV_SOURCE=%NX_DEST_DIR%\00_DEFAULTS\UGII\ugii_env.dat
set ENV_DESTINATION=C:\temp\ugii_env.dat

rem --- Einstellungen anzeigen
echo --- Set locations
echo Source Directory:      %EA_SOURCE_DIR%
echo Destination Directory: %NX_DEST_DIR%
echo Source ENV-file:       %ENV_SOURCE%
echo Destination ENV_file:  %ENV_DESTINATION%
echo.

echo Start synchronization process
pause
echo.

rem UGII_ENV.DAT sichern
echo.
echo Save ugii_env.dat
copy %ENV_SOURCE% %ENV_DESTINATION% /Z
rem Überprüfen ob die Datei gesichert wurde, sonst abbrechen
if not exist %ENV_DESTINATION% goto FEHLER

rem Synchronisieren
echo.
echo Synchronize UG to NX
robocopy "%EA_SOURCE_DIR%" "%NX_DEST_DIR%" /MIR /R:3 /W:30 /Log:"%LOG_DIR%\SyncLog_UgToNx.txt"

rem UGII_ENV.DAT zurückspielen
echo.
echo Restore ugii_env.dat
copy %ENV_DESTINATION% %ENV_SOURCE% /Z
rem Bereinigen
if exist %ENV_DESTINATION% del %ENV_DESTINATION%

rem Synchronisation fertig
echo.
echo Synchronization finished
echo See logfile SyncLog_UgToNx.txt in %LOG_DIR%
echo.
pause
goto EOF

:FEHLER
cls
echo Fatel Error!
echo File ugii_env.dat could not be backed up.
echo Script will be abort.
echo.
pause