@echo off
rem 
rem bcprt
rem This software and related documentation are proprietary to UGS Corp.
rem COPYRIGHT 2007 UGS CORP.  ALL RIGHTS RESERVED
rem ecprt

setlocal enabledelayedexpansion

set JRE_HOME=C:\CAD\JAVA\jre1.8.0_162
set JRE64_HOME=C:\CAD\JAVA\jre1.8.0_162

rem Save the launching directory
chdir /d %0\..
SET STARTDIR=%CD%

rem This is necessary if the user is running from a root directory
for %%I in ( %STARTDIR% ) do if %%I==%%~dI\ (
set STARTDIR=%STARTDIR%\
)

rem these are the only required jars to start tem. Rest of the will be loaded inside tem.
set JARS3=".\install\commons-lang.jar";".\install\jdom.jar";".\install\tem.jar"

set TEM_RMDEBUG=
set WINDOWED=
for %%A in (%*) do (
    if "%%A" equ "-rmdebug" set TEM_RMDEBUG=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000

    set WINDOWED=1
)
if defined TWEAKER set WINDOWED=1

set JRE_VERSION=1.8.0_20
set TEM_JRE=
if not exist tem_init.bat goto :parse_jre_home

call tem_init.bat
if exist %TC_JRE_HOME%\bin\java.exe (
set TEM_JRE=%TC_JRE_HOME%
set VALIDATE_TEM_JRE=
goto :set_java_command
)

:parse_jre_home
set VALIDATE_TEM_JRE=1
for %%A in (%*) do (
	if defined TEM_JRE set TEM_JRE=%%~A&goto :set_java_command
	if "%%A" equ "-jre"  set TEM_JRE=1
)

if exist %JRE64_HOME%\bin\java.exe (
set TEM_JRE=%JRE64_HOME%
set TEM_JRE_HOME_NAME=JRE64_HOME
goto :set_java_command
)

if exist %JRE_HOME%\bin\java.exe (
set TEM_JRE_HOME_NAME=JRE_HOME
set TEM_JRE=%JRE_HOME%
goto :set_java_command
)

:set_java_command
set JAVA_COMMAND=%TEM_JRE%\bin\javaw.exe
if defined WINDOWED set JAVA_COMMAND=%TEM_JRE%\bin\java.exe
if not defined VALIDATE_TEM_JRE goto :start_tem

:validate_tem_jre
if not exist "%JAVA_COMMAND%" (
echo Unable to locate Java at "%JAVA_COMMAND%". Please define JRE home path by command-line parameter '-jre' or environment variable %TEM_JRE_HOME_NAME%. Please use double-quotes on the parameter when using '-jre' and the path contains space characters. The version should be no older than %JRE_VERSION%.
if not defined WINDOWED pause
exit /b 1
)
rem disabling plugin.jar check of openJDK
rem if not exist "%TEM_JRE%\lib\plugin.jar" (
rem echo Unable to locate required Java Runtime Environment libraries at "%TEM_JRE%\lib". Please define the path to a JRE, not rem JDK, no older than %JRE_VERSION% by command-line parameter '-jre' or environment variable %TEM_JRE_HOME_NAME%.
rem if not defined WINDOWED pause
rem exit /b 1
rem )

"%TEM_JRE%\bin\java.exe" -cp %JARS3% com.teamcenter.install.util.struct.JreChecker -version %JRE_VERSION% -jre "%TEM_JRE%"

if not %ERRORLEVEL% equ 0 (
echo Specified JRE is not valid. Please provide another JRE by command-line parameter '-jre' or environment variable %TEM_JRE_HOME_NAME%. The version should be no older than %JRE_VERSION%.
if not defined WINDOWED pause
exit /b 1
)

:start_tem
"%TEM_JRE%\bin\java.exe" -cp %JARS3% com.teamcenter.install.tem.tasks.PruneTask

rem the jars will be loaded dynamically when starting tem to remove duplicates
set JARS=
for /d %%D in ( .\install;%TEM_PATH% ) do for %%I in ( %%D\*.jar) do if not defined JARS (
set JARS="%%I"
) else (
set JARS=!JARS!;"%%I"
)

set LEGACY_ENCODING=-Dsun.locale.formatasdefault=true
set JAVA_COMMAND_LINE="%JAVA_COMMAND%" %TEM_RMDEBUG% -Xms128M -Xmx512M %LEGACY_ENCODING% -DSTART_DIR="%STARTDIR%" %TEM_SPLASH% -Djava.library.path="./install" -cp %JARS% com.teamcenter.install.tem.struct.Tem %*
if defined WINDOWED (  
%JAVA_COMMAND_LINE%
) else (
start "" %JAVA_COMMAND_LINE%
)